Path: ibmpcug!wendy.ibmpcug.co.uk!pipex!howland.reston.ans.net!math.ohio-state.edu!hobbes.physics.uiowa.edu!dunix.drake.edu!acad.drake.edu!pk6811s
From: pk6811s@acad.drake.edu
Newsgroups: rec.games.corewar
Subject: Re: Good paper products
Date: 29 Mar 95 09:20:14 CST
Organization: Drake University, Des Moines, Iowa
Lines: 76
Distribution: world
Message-ID: <1995Mar29.092014@acad.drake.edu>
References: <1995Mar26.175513.2271@rhodes> <796384099snz@buchanan.demon.co.uk>
NNTP-Posting-Host: acad.drake.edu

>          graham@harlie.mathcs.rhodes.edu "Randy Graham" writes:
> 
>> there or not).  Any way, I was wondering if someone could give me a
>> good paper product to test against.  I have flashpaper, gammapaper,
>> and Silk warrior 1.3.  I do great against silk 1.3 and FlashPaper, and
>> OK against gamma.  Could someone send me a tougher paper to test
>> against so I can tell how I am going to do in long runs against paper.
>  

Paper Dreaming is a Silk-based replicator in which I experimented with
several 'enhancements'.  First was to use a starting copy distance which
is a high-mod number, in this case mod-160.  Mod-160 means that in the
50th generation Paper Dreaming starts overwriting older copies of itself
with the idea of restoring spl-bombed code to activity.  Unfortunately
you rarely get 50 generations against spl-carpet bombing scanners :-(

Second enhancement was to spl back to start immediately after the mov
statement, to keep the replication activity at as high a level as possible.
Bombing instructions follow that spl and are left to die upon completion.

Third enhancement was to use a large number of processes - 16.  This
means that the copied code is largely dat's, which reduces the number
of ties that occur when the copying code overwrites the opponent's
active instruction.

Fourth enhancement was to take advantage of knowing where and when the
offspring is executing, which allows an add/mov combination similar
to stones.  Step-bombing is much deadlier against scanners than 
incremental or decremental so it picks up a few quick wins.

Paul Kline
pk6811s@acad.drake.edu

;redcode-94 quiet
;name Paper Dreaming
;kill Paper Dreaming
;author P.Kline
;strategy paper experiments
;macro

len     equ 16
incr    equ 4320                ; high-mod separation
dec1    equ 5334
dec2    equ 2667
step    equ 13
     for 10
        dat   #1,1              ; decoy to tie Agony up during startup
        dat   1,#1
     rof
     for 45
        dat   0,0
     rof
start   spl 1,>100
        spl 1,>200
        spl 1,>300
        spl 1,>400              ; create 16 processes
        mov   <1,{1
        spl   s1+3040-320+len,s1+len
        
s1      spl   incr,0
sd      mov   >s1,}s1
        spl   s1,<s1
        mov   sc,   >s1-(2*incr)-(15*step)-14       ; here is where we bomb
        add   #step, s1-(2*incr)-(15*step)-14+incr  ; increment son's bombing
sp      mov   sb,>s1-(2*incr)-dec2                  ; more bombing
sp      dat   >s1-(2*incr)-dec2+incr,>s1-(2*incr)-dec2+incr ; triple-incr above
sb      dat   <dec1,<dec2
        dat   0,0
        dat   0,0               ; 3-spacer helps against Taking Names
        dat   0,0
sc      dat   1,1               ; all these dat 1,1's throw Torch's timing off
        dat   1,1
        dat   1,1
        dat   1,1
        dat   1,1
        end start