From news-rocq.inria.fr!univ-lyon1.fr!swidir.switch.ch!scsing.switch.ch!news.dfn.de!darwin.sura.net!howland.reston.ans.net!usc!elroy.jpl.nasa.gov!jlayland Thu Feb  3 16:37:21 1994
Article: 341 of rec.games.corewar
Path: news-rocq.inria.fr!univ-lyon1.fr!swidir.switch.ch!scsing.switch.ch!news.dfn.de!darwin.sura.net!howland.reston.ans.net!usc!elroy.jpl.nasa.gov!jlayland
From: jlayland@kilroy.jpl.nasa.gov (James Layland)
Newsgroups: rec.games.corewar
Subject: SJ-4a
Date: 2 Feb 1994 17:34:50 GMT
Organization: Jet Propulsion Laboratory, Pasadena, CA  USA
Lines: 90
Message-ID: <2ioo7q$h2@elroy.jpl.nasa.gov>
NNTP-Posting-Host: 128.149.63.2

Here is the code for SJ-4a, a SPL-JMP bomber inspired by Leprechaun 1b.
The two-pass clear and gate are not quite good enough to kill short 
imp spirals-- it is most annoying to see them get stunned up to the
process limit, then revive during the second pass and hit me before
the gate kicks in.  Something to work on in my copious spare time.

The big change from Leprechaun or other fighters using this B-scanning/
bombing strategy is that I bomb with JMP instructions, rather than
conventional bombs like SPLs or DATs.  The program checks the B-field of
the instruction pointed to by the JMP instruction.  If it is zero, the
program loops to bomb another address; otherwise it drops a SPL-JMP bomb
at the targeted location. 

Against scanners, the JMP instructions are probably lethal, so I act like
a 2/3-c bomber.  Against paper, I am almost as effective as dropping two 
SPL-JMP bombs per 7-instruction loop, which is slightly faster than a
straightforward SPL-JMP bomber, which uses 4 instructions per bomb.
Battles with Winter Werewolf and Imprimis are roughly even; but I lose to
conventional bombers (too fast) and most imp-spirals (bombers too fast, plus
the reincarnating spirals mentioned above).

My original idea in developing this was to create a Leprechaun-style 
vampire, but I could not figure out how to do what I wanted (I needed 
double-indirect addressing @@).  I did not put much effort into optimizing
the constants (beyond debugging the 2-pass core clear), and I have a few
ideas on modifying the core clear, but this is the version on KotH for
the last two months.
 
;redcode
;name SJ-4a
;author J.Layland
;strategy  Leprechaun-like SPL-JMP bomber, 2-pass clear, gate
	
inc equ -16*7	; mod 16 bomb		
offset equ 24	; mod 8 overall
b equ scan-offset
loc equ b+1+48
 
bomb dat <-49, #0
 
start add #inc, scan
mov j1, @scan
scan jmz -2, @test+offset
;xbreak
mov scan, @2	; dec protected
test mov j2, @b
mov s, <b
jmn start, test 
;xbreak
s   spl 0, <-48	 
    mov @b, <loc
j2  jmp -1,  0
j1  jmp -offset, -offset
src dat #0

ptr dat #-97

boot
mov ptr, <dst
sub #16, dst

mov <src, <dst
mov <src, <dst
mov <src, <dst
mov <src, <dst
mov <src, <dst

mov <src, <dst
mov <src, <dst
mov <src, <dst
mov <src, <dst
mov <src, <dst

mov <src, <dst

dst spl @0, 2356

sub #69, dst
mov bomb, <dst
 
mov 1, dst

; insert zero b-field decoy here...

end boot


-- 
James Layland
jlayland@grissom.jpl.nasa.gov