From corewar-l@stormking.com  Sun May 26 21:32:11 1996
Received: by couchey.inria.fr (5.57/Ultrix3.0-C)
	id AA05874; Sun, 26 May 96 21:32:11 +0200
Received: from uu3.psi.com (uu3.psi.com [38.145.250.2]) by nez-perce.inria.fr (8.7.1/8.7.1) with SMTP id VAA01591 for <damien.doligez@inria.fr>; Sun, 26 May 1996 21:32:08 +0200 (MET DST)
Received: by uu3.psi.com (5.65b/4.0.940727-PSI/PSINet) via UUCP;
        id AA23327 for ; Sun, 26 May 96 15:00:56 -0400
Received: from  (server@localhost [127.0.0.1]) by valhalla.stormking.com (8.6.12/8.6.12) with SMTP id OAA14247; Sun, 26 May 1996 14:28:04 -0400
Date: Sun, 26 May 1996 14:28:04 -0400
Message-Id: <4o9h0g$j64@sparcserver.lrz-muenchen.de>
Errors-To: tuc@stormking.com
Reply-To: guenzel@extern.lrz-muenchen.de
Originator: corewar-l@stormking.com
Sender: corewar-l@stormking.com
Precedence: bulk
From: guenzel@extern.lrz-muenchen.de (Bjoern Guenzel)
To: Multiple recipients of list <corewar-l@stormking.com>
Subject: blue candle
X-Listprocessor-Version: 6.0b -- ListProcessor by Anastasios Kotsikonas
X-Comment: Usenet News "rec.games.corewar"

Here is blue candle, yet another stone/spiral. While other imp-stones
often do better overall, blue candle seems to have more wins against
most other imp-stones at the moment, lucky for me.
When I wrote the stone, I was thinking it was a new idea, but in the
meantime I found out about Herem/Scimitar, Pac Man and others...
In future versions I should find a way to make it more resistant
against djn-streams.
I like the symmetrie of the boot, as both components are 8 lines to
boot. 
I chose a binary-launch because it is faster, I haven't tested a
add/jump launch, because it was so difficult to find the right moment
to hit it with a bomb. 

blue candle is also the second component in 'the historian'.



Bjoern




;redcode-94
;name blue candle
;author bjoern guenzel
;strategy stone/spiral
;strategy synchrone boot (to make it sound more interesting :->)
;strategy release 19.5.96
;assert CORESIZE==8000
;kill candle

;constants for blue x-torch
stshift		equ (-1234)	;boot distance
gate		equ hit+5001
sign		equ (-1)	
step4		equ (3364)	
step		equ (sign*step4)
magic		equ (1000)

;constants for spiral launch
istep		equ 2667
spshift		equ (ptr+stshift+imagic) ;magic boot distance
imagic      	equ (4875-1451+11)

 		
;launch stone
stlaunch z for 8
		mov.i {stsource,<booptr
rof
stboot		jmp @booptr,>1000


;launch spiral and stone
splaunch	spl stlaunch,>2001	;start here
for 8
		mov.i {spsource,{booptr
rof
		spl @booptr,>3002	;put a second processes into stone!
booptr		spl spsource+spshift,stsource+stshift
		mov.i #0,booptr		
		dat >4003,>5004		

; ************ blue x-torch ***********

clptr		dat 0,0
		dat 0,0
		dat 0,0			
steps		spl #2*step,-step 	;doubles as bomb
loop		add.x steps,ptr		
ptr		mov.i >ptr+magic*step,@hit+step
		mov.i steps,@ptr
hit		djn.f loop, <gate	;bombed with spl 
		mov.i bomb,>clptr
		djn.f -1,{clptr
bomb		dat #-1,<bomb-clptr+2	;bomb for clear

stsource    	dat 0,0

; ************ binspiral *************

		spl #-1000,>2000	;bombed after 15 process
		spl 4,>-1		;spiral has been created
		spl 2,}j3
j1		jmp imp-1,}0
j2		jmp imp+istep-1,}0
		nop }j1,}j2
j3		jmp imp+2*istep-1,}0
imp		mov.i #istep,istep

spsource    	dat 0,0


z for (MAXLENGTH-CURLINE)/2
		spl #z+z*1237,#-z-z*1237
		stp.ab >0,#z
rof

		end splaunch